Subversion Repositories factorylink.flntsys

Rev

Blame | Last modification | View Log | Download 

; -- SendMail.iss --
; Copyright (C) 2002 RLD Automation
; FL7.0, Windows 2000

[Setup]
AdminPrivilegesRequired=no
DisableStartupPrompt=yes
DisableProgramGroupPage=yes
DiskSpanning=0
AppName=Wizard Information Systems FactoryLink NT System Utilities (FL70, NT4 or Windows 2000)
AppVerName=FlNTsys Version 2.0, for FL7.0 NT4 (with SP4 or higher) or Windows 2000
AppCopyright=Copyright © 2002 RLD Automation.
DefaultDirName={code:GetPrgDir|{pf}\FlNTsys}
;DefaultGroupName=Wizard Information Systems
DirExistsWarning=no
MinVersion=4,4
OutputDir=..\..\Setup\Fl70
WizardImageFile=..\WizardFlNTsys.bmp
WizardSmallImageFile=..\FlNTsysSmallImage.bmp
UsePreviousAppDir=yes
Uninstallable=yes
UninstallDisplayIcon={app}\flntsys.exe
UninstallDisplayName=FactoryLink NT System Utilities
UninstallFilesDir={app}
AppPublisher=Wizard Information Systems
AppVersion=2.0
AppPublisherURL=http://www.wizinfosys.nl/
AppSupportURL=support@wizinfosys.nl
AppUpdatesURL=http://www.wizinfosys.nl/
LicenseFile=..\license.txt
;InfoBeforeFile=..\infobefore.txt
WizardStyle=modern
UninstallStyle=modern
WindowVisible=no
BackColor=clSilver
BackColor2=clBlack
BackColorDirection=toptobottom

[Types]
Name: full; Description: Full installation, server and client
;Name: "server"; Description: "Server only installation, FactoryLink task"
Name: custom; Description: Custom installation; Flags: iscustom

[Components]
Name: main; Description: System files and documentation; Types: full custom; Flags: fixed
Name: server; Description: Server; Types: full
Name: client; Description: Client; Types: full
[Files]
;FactoryLink files
Source: ..\..\Flink\Ac\FlNTsys.ac; DestDir: {app}\ac; Components: server
;Source: "..\..\Flink\Ac\FlNTsys.acr"; DestDir: "{app}\ac"
Source: ..\..\Flink\Ac\FlNTsys.h; DestDir: {app}\ac; Components: server
Source: ..\..\Source\FlNTsys\Fl70\Release\FlNTsys.exe; DestDir: {app}\bin; Components: server; Flags: ignoreversion
Source: ..\..\Flink\Bin\FlMsgRLD.dll; DestDir: {sys}; Flags: uninsneveruninstall; Components: server
Source: ..\..\Flink\Bin\RLDTitle.exe; DestDir: {sys}; Flags: uninsneveruninstall; Components: server
Source: ..\..\Flink\Ctgen\FlNTsys.ctg; DestDir: {app}\ctgen; Components: server
Source: ..\..\Flink\Ctgen\FlNTsys.rtm; DestDir: {app}\ctgen; Components: server
Source: ..\..\Flink\Help\FlNTsys.hlp; DestDir: {app}\help\de; Components: server
Source: ..\..\Flink\Help\FlNTsys.ahs; DestDir: {app}\help\de; Components: server
Source: ..\..\Flink\Help\FlNTsys.hlp; DestDir: {app}\help\en; Components: server
Source: ..\..\Flink\Help\FlNTsys.ahs; DestDir: {app}\help\en; Components: server
Source: ..\..\Flink\Help\FlNTsys.hlp; DestDir: {app}\help\fr; Components: server
Source: ..\..\Flink\Help\FlNTsys.ahs; DestDir: {app}\help\fr; Components: server
Source: ..\..\Flink\Key\En\NTbutton.key; DestDir: {app}\key\de; Components: server
Source: ..\..\Flink\Key\En\NTbutton.key; DestDir: {app}\key\en; Components: server
Source: ..\..\Flink\Key\En\NTbutton.key; DestDir: {app}\key\fr; Components: server
Source: ..\..\Flink\Key\En\NTevent.key; DestDir: {app}\key\de; Components: server
Source: ..\..\Flink\Key\En\NTevent.key; DestDir: {app}\key\en; Components: server
Source: ..\..\Flink\Key\En\NTevent.key; DestDir: {app}\key\fr; Components: server
Source: ..\..\Flink\Key\En\NTicon.key; DestDir: {app}\key\de; Components: server
Source: ..\..\Flink\Key\En\NTicon.key; DestDir: {app}\key\en; Components: server
Source: ..\..\Flink\Key\En\NTicon.key; DestDir: {app}\key\fr; Components: server
Source: ..\..\Flink\Key\En\NTshut.key; DestDir: {app}\key\de; Components: server
Source: ..\..\Flink\Key\En\NTshut.key; DestDir: {app}\key\en; Components: server
Source: ..\..\Flink\Key\En\NTshut.key; DestDir: {app}\key\fr; Components: server
Source: ..\..\Flink\Key\En\NTsyskey.key; DestDir: {app}\key\de; Components: server
Source: ..\..\Flink\Key\En\NTsyskey.key; DestDir: {app}\key\en; Components: server
Source: ..\..\Flink\Key\En\NTsyskey.key; DestDir: {app}\key\fr; Components: server
Source: ..\..\Flink\Key\En\NTsysky2.key; DestDir: {app}\key\de; Components: server
Source: ..\..\Flink\Key\En\NTsysky2.key; DestDir: {app}\key\en; Components: server
Source: ..\..\Flink\Key\En\NTsysky2.key; DestDir: {app}\key\fr; Components: server
Source: ..\..\Flink\Mps\En\Fl70\FlNTsys.mps; DestDir: {app}\mps\en; Components: server
Source: ..\..\Flink\Mps\En\Fl70\FlNTsys.cba; DestDir: {app}\mps\en; Components: server
Source: ..\..\Flink\Msg\En\FlNTsys.txt; DestDir: {app}\msg\de; Components: server
Source: ..\..\Flink\Msg\En\FlNTsys.txt; DestDir: {app}\msg\en; Components: server
Source: ..\..\Flink\Msg\En\FlNTsys.txt; DestDir: {app}\msg\fr; Components: server
Source: ..\..\Flink\Msg\En\NTsys_ac.txt; DestDir: {app}\msg\de; Components: server
Source: ..\..\Flink\Msg\En\NTsys_ac.txt; DestDir: {app}\msg\en; Components: server
Source: ..\..\Flink\Msg\En\NTsys_ac.txt; DestDir: {app}\msg\fr; Components: server
;Keyboard filter driver
Source: ..\..\Source\KbFilter\KbFilter.sys; DestDir: {sys}\drivers; Flags: restartreplace; Components: main
Source: ..\..\Source\KbFilter\KbFilter.reg; DestDir: {sys}\drivers; Components: main
;Keyboard filter ActiveX component
Source: ..\..\Source\KeyboardFilter\Release\KeyBoardFilter.ocx; DestDir: {sys}; Flags: regserver; Components: client
;Documentation
Source: {src}\FlNTsys.pdf; DestDir: {app}\..\Documentation\en; Flags: external; Components: main
;Source: "..\..\Manual\Fl70\FlNTsysNote.rtf"; DestDir: "{app}\bin"; Components: main

[Registry]
Root: HKLM; Subkey: Software\RLD Automation\FactoryLink NT Sytem Utilities; ValueType: string; ValueName: Serial; ValueData: ; Flags: createvalueifdoesntexist; Components: main
Root: HKLM; Subkey: Software\RLD Automation\FactoryLink NT Sytem Utilities; ValueType: binary; ValueName: Registration; ValueData: ; Flags: createvalueifdoesntexist; Components: main
;Keyboard filter
Root: HKLM; Subkey: SYSTEM\CurrentControlSet\Services\KbFilter; Flags: createvalueifdoesntexist; Components: main
Root: HKLM; Subkey: SYSTEM\CurrentControlSet\Services\KbFilter; ValueType: dword; ValueName: ErrorControl; ValueData: 1; Components: main
Root: HKLM; Subkey: SYSTEM\CurrentControlSet\Services\KbFilter; ValueType: dword; ValueName: Type; ValueData: 1; Components: main
Root: HKLM; Subkey: SYSTEM\CurrentControlSet\Services\KbFilter; ValueType: dword; ValueName: Start; ValueData: 2; Components: main
Root: HKLM; Subkey: SYSTEM\CurrentControlSet\Services\KbFilter; ValueType: string; ValueName: Group; ValueData: Keyboard Class; Components: main
Root: HKLM; Subkey: SYSTEM\CurrentControlSet\Services\KbFilter; ValueType: string; ValueName: DisplayName; ValueData: Keyboard Filter; Components: main
;Update utility launcher and autostart service
Root: HKLM; Subkey: Software\Classes\AppID\{{6BE98583-87A6-11D1-9B6C-0020AF1E9F09}; ValueType: string; ValueName: RunAs; ValueData: Interactive User; Flags: createvalueifdoesntexist; Components: server
Root: HKLM; Subkey: System\CurrentControlSet\Services\FactoryLink Autostart Service; ValueType: string; ValueName: ObjectName; ValueData: LocalSystem; Components: server

[Run]
Filename: {app}\bin\acctmgr.exe; Parameters: -c -d -v; Check: MyTitles; Flags: runminimized; StatusMsg: Updating FactoryLink account manager index...; Components: server
Filename: {app}\bin\mkhelp.exe; Flags: runminimized; StatusMsg: Updating FactoryLik help file index...; Components: server

[UninstallRun]
Filename: {sys}\RLDTitle.exe; Parameters: " /REMOVE=flntsys"; Flags: runminimized; StatusMsg: Updating FactoryLink account manager index...; Components: server
Filename: {app}\bin\acctmgr.exe; Parameters: -c -d -v; Flags: runminimized; StatusMsg: Updating FactoryLink account manager index...; Components: server

[InstallDelete]
;Type: files; Name: "{app}\FlInstall.exe"

[Messages]
RunEntryShellExec=Yes, I would like to view the README file

[Code]
var
  DriverList: String;
  TaskName: String;

function InitializeSetup(): Boolean;
{var
  MyText: String;}
begin

  {Task name specification, name is a constant of the code section}
  TaskName := 'sendmail';

  RegQueryStringValue(HKLM, 'SOFTWARE\USDATA\FactoryLink\Configuration Explorer\Menus\Node Classes\NC_TASKGROUP', 'Task Group Device Interfaces', DriverList);

  {create a driver list if there is none}
  if (DriverList = '') then begin

    DriverList := 'scale,ioxlator,edi_dev,te__,mbus,modp,mbustcp,sqrd,ab__,ab__rapd,netdtl,ktdtl,gene,asyn,omrn,sdrv,siem,h1mp,ti__,omux,ov60,mist,ldnr,t405,reli,gem_,dan2,eibi,apac2,bn90,dmod,es__,moor,rocm,tmdm,rmdm,hdp_rocm,bris,profibus,sinec_h1,s_3964r,stple,stplcnfg';
  end;

  {add our task to the driver list}
  if (Pos(TaskName,  DriverList) = 0) then begin

    DriverList := DriverList + ',' + TaskName;
  end;

  Result := True;
end;

{Read the FactoryLink directory from the autostart service program location,
 using the environment variable FLINK will result in a directory with
 short names. By using the autostart server the long names are found, and
 the setup progam will use these names instead of the notation in short}
function GetPrgDir(S: String): String;
var
  MyDir: String;
begin

  {read the autostart service directory, filename and extension}
  RegQueryStringValue( HKEY_LOCAL_MACHINE, 'System\CurrentControlSet\Services\FactoryLink Autostart Service', 'ImagePath', MyDir);

  {remove the filename and last '\' character}
  MyDir := ExtractFileDir( MyDir);

  {now the bin subdir is removed.....}
  MyDir := ExtractFileDir( MyDir);

  {return default in case no directory is found}
  if (Length( MyDir) <= 0) then begin
    MyDir := S;
  end;

  {return the directory to install the program}
  Result := MyDir;
end;

{Get the driver string for modifying the tree view of the
 Configuration Explorer}
function GetDriverString(DefaultInput: String): String;
begin
  { Return the driver list }
  Result := DriverList;
end;

{Add a AC line for the current task to the titles file, add a line
 to the CTlist file. The taskname and ct-line are specified in the
 function-parameter: taskname,ct-line}
function AddTitle( MyEntry: String): Boolean;
var
  MyText: TArrayOfString;
  MyFile: String;
  MyAC: String;
  MyCT: String;
  k: Integer;
  found: Integer;
begin

  {first file to load is th etitles file in the AC directory}
  MyFile := GetPrgDir( '') + '\ac\titles';
  k := LoadStringsFromFile( MyFile, MyText);

  {AC entry looks like: taskname.ac}
  k := Pos( ',', MyEntry);
  if k = 0 then k := Pos( ':', MyEntry);
  MyAC := Copy( MyEntry, 0, k-1) + '.ac';
  MyCT := MyEntry;
  StrSet( ':', k, MyCt);

  {search for ac entry}
  found := 0;
  k := 0;
  while (k < GetArrayLength(MyText)) and (not found) do begin

    found := Pos( MyAC, MyText[ k]);
    k := k + 1;
  end;

  {if the entry is not found, add a line to the titles file}
  if (found = 0) then begin

    SetArrayLength(MyText, GetArrayLength(MyText)+1);
    MyText[ GetArrayLength(MyText)-1] := MyAC;
    SaveStringsToFile( MyFile, MyText, false);
  end;

  {add entry to ctlist file}
  MyFile := GetPrgDir( '') + '\ctgen\ctlist';
  k := LoadStringsFromFile( MyFile, MyText);

  {search for ctgen entry}
  found := 0;
  k := 0;
  while (k < GetArrayLength(MyText)) and (not found) do begin

    found := Pos( MyCT, MyText[ k]);
    k := k + 1;
  end;

  {if the entry is not found, add a line to the ctlist file}
  if (found = 0) then begin

    SetArrayLength(MyText, GetArrayLength(MyText)+1);
    MyText[ GetArrayLength(MyText)-1] := MyCT;
    SaveStringsToFile( MyFile, MyText, false);
  end;

  {return always true, ac file must be installed, this function
   only adds a line to the titles file}
  Result := True;
end;

{Remove a AC line for the current task in the titles file, and remove
 a line in the CTlist file the entry is specified with the task name
 in the function-parameter}
function RemoveTitle( MyEntry: String): Boolean;
var
  MyText: TArrayOfString;
  MyFile: String;
  MyAC: String;
  MyCT: String;
  Temp: String;
  k: Integer;
  found: Integer;
begin

  MyAC := MyEntry + '.ac';
  MyCT := MyEntry + ':';

  {search the task name in the ctlist file}
  MyFile := GetPrgDir( '') + '\ctgen\ctlist';
  SetArrayLength( MyText, 0);
  k := LoadStringsFromFile( MyFile, MyText);

  {search for the task name}
  for k:=0 to GetArrayLength(MyText)-1 do begin

    Temp := MyText[ k];
    if (found = 0) then
      found := Pos( MyCT, MyText[ k]);

    {if the entry is found, remove the line from the titles file}
    if (found) then begin

      if ((k+1) < GetArrayLength(MyText)) then begin

        MyText[ k] := MyText[ k+1];
      end else {begin;}
        MyText[ k] := '';
    end;
  end;

  if (found) then begin

    {shorten array with one}
    SetArrayLength( MyText, GetArrayLength( MyText) - 1);
    SaveStringsToFile( MyFile, MyText, false);
  end;

  {search the task name in the titles file}
  MyFile := GetPrgDir( '') + '\ac\titles';
  k := LoadStringsFromFile( MyFile, MyText);
  found := 0;

  {search for the task name}
  for k:=0 to GetArrayLength(MyText)-1 do begin

    Temp := MyText[ k];
    if (found = 0) then
      found := Pos( MyAC, MyText[ k]);

    {if the entry is found, remove the line from the titles file}
    if (found) then begin

      if ((k+1) < GetArrayLength(MyText)) then begin

        MyText[ k] := MyText[ k+1];
      end else {begin;}
        MyText[ k] := '';
    end;
  end;

  if (found) then begin

    {shorten array with one}
    SetArrayLength( MyText, GetArrayLength( MyText) - 1);
    SaveStringsToFile( MyFile, MyText, false);
  end;

  {return always true, ac file must be removed}
  Result := True;
end;

{Add both task entries in TITLES en CTLIST file}
function MyTitles(): Boolean;
begin
  AddTitle('flntsys,ntsys_k ntsys_s ntsys_m');
  Result := True;
end;